Kết nối module cảm biến nhiệt độ DHT11 với Arduino

Module cảm biến DHT11 cũng bao gồm một IC 8-bit. IC này đo và xử lý tín hiệu analog, chuyển đổi tín hiệu analog sang tín hiệu digital và xuất ra tín hiệu digital chứa dữ liệu nhiệt độ và độ ẩm.

Kết nối module DHT11 với Arduino

Kết nối module DHT11 với Arduino tương đối đơn giản vì module chỉ có ba chân:

• VCC(+): Chân này cung cấp nguồn điện cho cảm biến. Mặc dù điện áp cung cấp của mô-đun này có thể dao động từ 3.3V đến 5.5V, nhưng nguồn điện 5V được khuyến nghị sử dụng. Với nguồn cung cấp 5V, cảm biến có thể được đặt cách xa vi điều khiển tới 20m. Với điện áp cung cấp 3.3V, cảm biến chỉ nên được đặt cách 1m nếu không sẽ gây ra hiện tượng sụt áp trên đường dây làm lỗi tín hiệu.
• OUT: Chân này được sử dụng để giao tiếp giữa cảm biến và vi điều khiển.
• GND(-): Đây là chân nối đất.

Bây giờ chúng ta hãy bắt đầu kết nối module DHT11 với Arduino!
Các kết nối tương đối đơn giản. Bắt đầu bằng việc kết nối chân VCC(+) với chân ra 5V của Arduino và chân GND(-) với chân GND. Cuối cùng, hãy kết nối chân OUT với một chân digital (ví dụ ở đây là chân D8).
Sơ đồ dưới đây cho thấy cách kết nối tất cả các thành phần.

Cài đặt thư viện cảm biến DHT

Cảm biến DHT có giao thức truyền dữ liệu của riêng chúng, giao thức này yêu cầu thời gian lấy mẫu chính xác. Tuy nhiên, chúng ta không cần lo lắng quá nhiều về điều này, vì chúng ta sẽ sử dụng thư viện DHTlib, thư viện này xử lý hầu hết mọi thứ.

Để cài đặt thư viện, bạn hãy chọn trên thanh menu của Arduino IDE: Sketch > Include Library > Manage Libraries… rồi tìm kiếm từ khóa “dhtlib”. Nhấp vào kết quả đó và sau đó chọn cài đặt (Install).

Ví dụ 1: Hiển thị và đọc thông số module cảm biến DHT11 trên Serial Monitor

Sau khi cài đặt thư viện, sao chép và dán đoạn mã này vào Arduino IDE.

Đoạn mã kiểm tra sau đây sẽ in giá trị nhiệt độ và độ ẩm tương đối vào màn hình serial. Hãy nạp thử đoạn code này vào board sau đó kết nối module cảm biến, chúng ta sẽ đi vào giải thích chi tiết hơn.

#include <dht.h>        // Include library
#define outPin 8        // Defines pin number to which the sensor is connected

dht DHT;                // Creates a DHT object

void setup() {
    Serial.begin(9600);
}

void loop() {
    int readData = DHT.read11(outPin);

    float t = DHT.temperature;        // Read temperature
    float h = DHT.humidity;           // Read humidity

    Serial.print("Temperature = ");
    Serial.print(t);
    Serial.print("°C | ");
    Serial.print((t*9.0)/5.0+32.0);        // Convert celsius to fahrenheit
    Serial.println("°F ");
    Serial.print("Humidity = ");
    Serial.print(h);
    Serial.println("% ");
    Serial.println("");

    delay(2000); // wait two seconds
}

Sau khi nạp đoạn mã, bạn sẽ thấy kết quả hiển thị ra trên Serial Monitor.

Giải thích đoạn code ví dụ 1:

Chúng ta bắt đầu bằng việc #include thư viện DHT. Sau đó, chúng ta #define chân tín hiệu thành chân D8 của cảm biến được kết nối và tạo một object tên là DHT.

#include <dht.h>
#define outPin 8

dht DHT;

Trong hàm setup(), chúng ta khởi tạo giao tiếp serial.

void setup() {
  Serial.begin(9600);
}

Trong hàm loop(), chúng ta sử dụng hàm read11() để đọc dữ liệu từ module DHT11. Hàm này nhận tham số là số chân kết nối dữ liệu của cảm biến.

Lưu ý: Thư viện DHT có thể có cả hàm read() và read11(). Tuy nhiên, hàm read11() được khuyến nghị sử dụng cho cảm biến DHT11 vì nó cung cấp độ chính xác cao hơn.

int readData = DHT.read11(outPin);

Bây giờ chúng ta có thể truy xuất các giá trị độ ẩm và nhiệt độ bằng cách truy cập vào các thuộc tính của object DHT.

float t = DHT.temperature;        // Read temperature
float h = DHT.humidity;           // Read humidity

Trong đoạn code trên, biến humidity sẽ lưu trữ giá trị độ ẩm tương đối và biến temperature sẽ lưu trữ giá trị nhiệt độ (theo thang độ C).

Bên cạnh đó, bạn có thể dễ dàng chuyển đổi giá trị nhiệt độ sang Fahrenheit (°F) bằng cách sử dụng công thức sau: T(°F) = T(°C) × 9/5 + 32

Serial.print((t * 9.0) / 5.0 + 32.0);

Lưu ý rằng các giá trị này có thể có độ chính xác nhất định tùy thuộc vào loại cảm biến DHT11 bạn đang sử dụng.

Ví dụ 2: Hiển thị giá trị module cảm biến DHT11 trên màn hình LCD

Nếu bạn muốn hiển thị giá trị nhiệt độ – độ ẩm mà không cần dùng Serial Monitor trên máy tính, bạn sẽ cần một màn hình LCD. Vì vậy trong ví dụ này, chúng tôi cũng sẽ kết nối LCD1602 với Arduino bên cạnh module DHT11.

Đây là giao diện hiển thị của LCD1602.

Chúng ta hãy kết nối LCD như hình bên dưới.

Đoạn mã dưới đây sẽ hiển thị giá trị nhiệt độ và độ ẩm tương màn hình LCD1602. Đoạn mã này tương tự như đoạn mã trong ví dụ 1, ngoại trừ việc các giá trị được in trên LCD.

#include <LiquidCrystal.h>      // Include LiquidCrystal Library
#include <dht.h>

#define outPin 8

LiquidCrystal lcd(12, 11, 5, 4, 3, 2); // Create an LCD object.
dht DHT;                // Create a DHT object

void setup() {
    lcd.begin(16,2); 	// Initialize the LCD
}

void loop() {
    int readData = DHT.read11(outPin);
    
    float t = DHT.temperature;
    float h = DHT.humidity;
    
    lcd.setCursor(0,0);
    lcd.print("Temp.: ");
    lcd.print(t);
    lcd.print((char)223);	//shows degrees character
    lcd.print("C");

    lcd.setCursor(0,1);
    lcd.print("Humi.: ");
    lcd.print(h);
    lcd.print("%");
    
    delay(2000);
}

nguồn: lastminuteengineers.com